石油ファンヒーター改造 (3: HomeKit対応ファンヒーター爆誕)

#include <EspMQTTClient.h>
#include <ArduinoOTA.h>

EspMQTTClient *client;

const int switchOn=1; //start switch
const int switchEx=0; //extention switch
const int ledOn=2; //LED for On or Off

//status of the fan heater
bool isExtendMode=false; //true: extend on every 150 min
bool isOn=false; //If fan heater is On (true) or Off (false)

//timer & counter using main loop
long int counter=0; //counter for extend-interval (used in loop())
//WiFi & MQTT
const char SSID[] = "XXXXXXXX"; //WiFi SSID
const char PASS[] = "xxxxxxxx"; //WiFi password
char CLIENTID[] = "ESP32_xx:xx:xx:xx:xx:xx"; //MAC address is set in setup()
//for example, this will be set to "ESP32_84:CC:A8:7A:5F:44"
const char MQTTADD[] = "192.168.xxx.xxx"; //Broker IP address
const short MQTTPORT = 1883; //Broker port
const char MQTTUSER[] = "XXXXXXXX";//Can be omitted if not needed
const char MQTTPASS[] = "xxxxxxxx";//Can be omitted if not needed
const char SUBTOPIC[] = "mqttthing/fanheater2/set"; //mqtt topic to subscribe
const char PUBTOPIC[] = "mqttthing/fanheater2/get"; //mqtt topic to publish
const char PUBDEBUG[] = "mqttthing/fanheater2/debug"; //for debug message

void onConnectionEstablished() {
  ArduinoOTA.setHostname("fanheater2");
  ArduinoOTA.setPasswordHash("99999999999999999999999999999999");
  ArduinoOTA.begin();
  client->subscribe(SUBTOPIC, onMessageReceived); //set callback function
  client->publish(PUBDEBUG,"Fan Heater 2 started.");
  pubCurrentStatus();
}

void pubCurrentStatus(){
  if(isOn) client->publish(PUBTOPIC,"ON");
  else client->publish(PUBTOPIC,"OFF");
  if(isExtendMode) client->publish(PUBTOPIC,"exON");
  else client->publish(PUBTOPIC,"exOFF");
}

void onMessageReceived(const String& msg) {
  client->publish(PUBDEBUG,"Message received.");
  if(msg.compareTo("ON")==0 && !isOn) pressSwitch(switchOn);
  else if(msg.compareTo("OFF")==0 && isOn) pressSwitch(switchOn);
  else if(msg.compareTo("exON")==0) {
    pressSwitch(switchEx);
    counter=0; //reset interval counter
    isExtendMode=true; //enable succeeding extension
  }
  else if(msg.compareTo("exOFF")==0) {
    pressSwitch(switchEx); //last extension
    isExtendMode = false; //desable succeeding extension
  }
}

void setup() {
  pinMode(ledOn, INPUT); //read the LED indicator
  pinMode(switchOn, OUTPUT); // On/Off switch
  digitalWrite(switchOn, HIGH);
  pinMode(switchEx, OUTPUT); // Extend switch
  digitalWrite(switchEx, HIGH);
  isExtendMode=false; //default value: no extension
  String wifiMACString = WiFi.macAddress(); //WiFi MAC address
  wifiMACString.toCharArray(&CLIENTID[6], 18, 0); //"ESP32_xx:xx:xx:xx:xx:xx"
  client = new EspMQTTClient(SSID,PASS,MQTTADD,MQTTUSER,MQTTPASS,CLIENTID,MQTTPORT);
  delay(1000);
}

void pressSwitch(int gpio) {
  digitalWrite(gpio, LOW); // turn the photo switch on
  delay(1000);
  digitalWrite(gpio, HIGH); // turn the photo switch off
}

static int counterLED=0;
void loop() {
  ArduinoOTA.handle(); //for OTA
  client->loop(); //for MQTT
  delay(100);
  if(digitalRead(ledOn) == LOW) { //Power-on LED is on
    counterLED=0;
    isOn = true;
  }else{ //Power-on LED is off
    if(++counterLED > 10){ //LED is off for >1sec.
      counterLED = 0;
      isOn = false;
    }
  }
  if(++counter > (150 * 60 * 10)) { //on every 150 min
    counter=0;
    if(isExtendMode) pressSwitch(switchEx);
  }
  if((counter % 300) == 0) // on every 30 sec, reports the mode
    pubCurrentStatus();
}

{
  "type": "switch",
  "name": "FH2 Extend",
  "topics": { 
    "getOn": "mqttthing/fanheater2/get", 
    "setOn": "mqttthing/fanheater2/set"
  },
  "onValue": "exON",
  "offValue": "exOFF",
  "accessory": "mqttthing" 
},
 
{
  "type": "switch",
  "name": "FH2 OnOff",
  "topics": {
    "getOn": "mqttthing/fanheater2/get",
    "setOn": "mqttthing/fanheater2/set" 
  }, 
  "onValue": "ON", 
  "offValue": "OFF", 
  "accessory": "mqttthing" 
}