ESP-01Sが安かったのでHomeKitで遊んでみる

const int BlueLED=2; //Onboard blue LED (ESP-01S)
//const int BlueLED=1; //Onboard blue LED (ESP-01)

void setup() {
  pinMode(BlueLED, OUTPUT); // Initialize the LED pin as an output
}

void loop() {
  digitalWrite(BlueLED, LOW); // Turn the LED on
  delay(100); // Wait for 100ms
  digitalWrite(BlueLED, HIGH); // Turn the LED off
  delay(900); // Wait for 900ms
}

#include <EspMQTTClient.h>
#include <ArduinoOTA.h>

EspMQTTClient *client; //pointer to MQTT instance
const char SSID[] = "XXXXXXXX"; //WiFi SSID
const char PASS[] = "xxxxxxxx"; //WiFi password
char CLIENTID[] = "ESP32_xx:xx:xx:xx:xx:xx"; //MAC address is set in setup()
const char MQTTADD[] = "192.168.xxx.xxx"; //Broker IP address
const short MQTTPORT = 1883; //Broker port
const char MQTTUSER[] = "xxxxxxxx";//Can be omitted if not needed
const char MQTTPASS[] = "XXXXXXXX";//Can be omitted if not needed

const int blueLED=2;

void setup() {
  pinMode(blueLED,OUTPUT);
  String wifiMACString = WiFi.macAddress(); //WiFi MAC address
  wifiMACString.toCharArray(&CLIENTID[6], 18, 0); //"ESP32_xx:xx:xx:xx:xx:xx"
  client = new EspMQTTClient(SSID,PASS,MQTTADD,MQTTUSER,MQTTPASS,CLIENTID,MQTTPORT);
  delay(1000);
}

void onConnectionEstablished() {
  ArduinoOTA.setHostname("ESP8266_OTA");
  ArduinoOTA.setPasswordHash("99999999999999999999999999999999");
  ArduinoOTA.begin();
}

static int counter=0;
void loop() {
  ArduinoOTA.handle(); //handle OTA
  client->loop(); //handle MQTT
  delay(100);
  counter++;
  if(counter==1) digitalWrite(blueLED,LOW); //turn on the LED
  if(counter==2) digitalWrite(blueLED,HIGH); //turn off the LED
  if(counter>=10) counter=0;
}

File "~/Library/Arduino15/packages/esp8266/hardware/esp8266/3.1.2/tools/espota.py", line 103, 
in serve sock2.sendto(message.encode(), remote_address) 
OSError: [Errno 65] No route to host 
Failed uploading: uploading error: exit status 1

#include <DHT20.h>
DHT20  *dht; //DHT20 instance

void setup(){
  dht = new DHT20();
  dht->begin(); //use default GPIO: 21,22
  
　//略
}

class DHT20
{
public:
  //  CONSTRUCTOR
  DHT20(TwoWire *wire = &Wire);
略
}

#include <Wire.h>
#include <DHT20.h>
const int pinSDA=0; //GPIO pins for I2C
const int pinSCL=2;
TwoWire *dht_wire; //pointer to I2C instance
DHT20 *dht; //pointer to DHT20 instance

void setup(){
  dht_wire = new TwoWire();
  dht_wire->begin(pinSDA,pinSCL); //assign GPIO
  dht = new DHT20(dht_wire); //use custom GPIO
  dht->begin(); 
  
　//略
}

#include <EspMQTTClient.h>
#include <ArduinoOTA.h>
#include <Wire.h>
#include <DHT20.h>

EspMQTTClient *client; //pointer to MQTT instance
const int pinSDA=0; //pins for I2C
const int pinSCL=2; //pins for I2C
TwoWire *dht_wire; //pointer to I2C instance
DHT20 *dht; //pointer to DHT20 instance

//WiFi & MQTT
const char SSID[] = "XXXXXXXX"; //WiFi SSID
const char PASS[] = "xxxxxxxx"; //WiFi password
char CLIENTID[] = "ESP32_xx:xx:xx:xx:xx:xx"; //MAC address is set in setup()
//for example, this will be set to "ESP32_84:CC:A8:7A:5F:44"
const char MQTTADD[] = "192.168.xxx.xxx"; //Broker IP address
const short MQTTPORT = 1883; //Broker port
const char MQTTUSER[] = "xxxxxxxx";//Can be omitted if not needed
const char MQTTPASS[] = "XXXXXXXX";//Can be omitted if not needed
const char SUBTOPIC[] = "mqttthing/esp01S/set"; //mqtt topic to subscribe
const char PUBTOPIC[] = "mqttthing/esp01S/get"; //mqtt topic to publish
const char PUBDEBUG[] = "mqttthing/esp01S/debug"; //for debug message

void onConnectionEstablished() {
  ArduinoOTA.setHostname("esp01S");
  ArduinoOTA.setPasswordHash("99999999999999999999999999999999");
  ArduinoOTA.begin();
  client->subscribe(SUBTOPIC, onMessageReceived); //set callback function
  client->publish(PUBDEBUG,"ESP01S temp/humi sensor started.");
  publishDHT();
}

void onMessageReceived(const String& msg) {
  client->publish(PUBDEBUG,"Message received.");
  publishDHT();
}

void setup() {
  String wifiMACString = WiFi.macAddress(); //WiFi MAC address
  wifiMACString.toCharArray(&CLIENTID[6], 18, 0); //"ESP32_xx:xx:xx:xx:xx:xx"
  client = new EspMQTTClient(SSID,PASS,MQTTADD,MQTTUSER,MQTTPASS,CLIENTID,MQTTPORT);
  dht_wire = new TwoWire();
  dht_wire->begin(pinSDA,pinSCL);
  dht = new DHT20(dht_wire);
  dht->begin();
  delay(1000);
}

void publishDHT() {
  char buff[64];
  float humi, temp;
  if(DHT20_OK != dht->read()){
    client->publish(PUBDEBUG,"DHT20 Read Error.");
  }else{
    humi=dht->getHumidity();
    temp=dht->getTemperature();
    sprintf(buff, "{\"temperature\":%.1f,\"humidity\":%.0f}", temp, humi);
    client->publish(PUBTOPIC,buff);
  }
}

void loop() {
  ArduinoOTA.handle(); //for OTA
  client->loop(); //for MQTT
  if(millis() - dht->lastRead() >= 30000) publishDHT(); //30sec
}

mqttthing/esp01S/get {"temperature":25.0,"humidity":43} mqttthing/esp01S/get {"temperature":25.1,"humidity":43} mqttthing/esp01S/get {"temperature":25.0,"humidity":43}

% mosquitto_pub -t "mqttthing/esp01S/set" -m ""

 mqttthing/esp01S/get {"temperature":25.1,"humidity":42}

{
  "type": "temperatureSensor",
  "name": "DHT20_temp",
  "username": "xxxxxxxx",
  "password": "XXXXXXXX",
  "topics": {
    "getCurrentTemperature": "mqttthing/esp01S/get$.temperature"
  },
  "accessory": "mqttthing"
},
{
  "type": "humiditySensor",
  "name": "DHT20_humi",
  "username": "xxxxxxxx",
  "password": "XXXXXXXX",
  "topics": {
    "getCurrentRelativeHumidity": "mqttthing/esp01S/get$.humidity"
  },
  "accessory": "mqttthing"
}