ESP-01を使ってセキュリティシステムを作る

//ESP-01 security system with EspMQTTClient library.

#include <arduinoota.h>
#include <espmqttclient.h>
EspMQTTClient *client; //instance of MQTT

//input & output pins and values
#define ALARMOUT 0 //GPIO for a relay to activate alarm buzzer.
#define ARMEDLED 1  //GPIO for armed-indicator LED.

//security level. Only AA (Away Arm) and D (Disarm) are used.
#define level_SA 0  //Stay Arm, not used in this version
#define level_AA 1  //Away Arm, this version uses this
#define level_NA 2  //Night Arm, not used in this version
#define level_D 3   //Disarm
int currentLevel=level_D; //current security level 0=SA, 1=AA, 2=NA, 3=D

//WiFi
const char SSID[] = "xxxxxxxx"; //WiFi SSID
const char PASS[] = "XXXXXXXX"; //WiFi password
//MQTT
char CLIENTID[] = "ESP32_xx:xx:xx:xx:xx:xx"; //MAC address is set in setup()
//for example, this will be set to "ESP32_84:CC:A8:7A:5F:44"
const char  MQTTADD[] = "192.168.xxx.xxx"; //Broker IP address
const short MQTTPORT = 1883; //Broker port
const char  MQTTUSER[] = "";//Can be omitted if not needed
const char  MQTTPASS[] = "";//Can be omitted if not needed
const char  SUBTOPIC[] = "mqttthing/security/setTargetState"; //mqtt topic to subscribe
const char  PUBCURRENT[] = "mqttthing/security/getCurrentState"; //mqtt topic to publish
const char  PUBDEBUG[] = "mqttthing/security/debug"; //for debug message

void setup() {
  //Digital I/O
  pinMode(ALARMOUT, OUTPUT);
  pinMode(ARMEDLED, OUTPUT);
  digitalWrite(ALARMOUT, HIGH); //set alarm off
  digitalWrite(ARMEDLED, HIGH); //set LED off
  currentLevel=level_D; //set disarm
  //MQTT
  String wifiMACString = WiFi.macAddress(); //WiFi MAC address
  wifiMACString.toCharArray(&CLIENTID[6], 18, 0); //"ESP32_xx:xx:xx:xx:xx:xx"
  client = new EspMQTTClient(SSID,PASS,MQTTADD,MQTTUSER,MQTTPASS,CLIENTID,MQTTPORT);
  delay(500);
}

void onConnectionEstablished() {
  ArduinoOTA.setHostname("ESP-01_security");
  ArduinoOTA.setPasswordHash("xxxxxxxxxxxxxxxxxxxxxxxxxx");
  ArduinoOTA.begin();
  client->subscribe(SUBTOPIC, onMessageReceived);
  client->publish(PUBDEBUG,"ESP-01 Security System is ready.");;
}

void onMessageReceived(const String& msg) {// topic: mqttthing/security/setTargetState
  client->publish(PUBDEBUG, "Set TS received.");

  if(msg.compareTo("alarmtest1")==0) { //test with 1sec. alarm for debug
    client->publish(PUBDEBUG, "Alarm test started.");
    digitalWrite(ALARMOUT, LOW); delay(1000); digitalWrite(ALARMOUT, HIGH);
    client->publish(PUBDEBUG, "Alarm test stopped.");
  }
  else if(msg.compareTo("AA")==0) { //is set AA
    currentLevel = level_AA;
    //indicate with a short beep
    digitalWrite(ALARMOUT, LOW); delay(20); digitalWrite(ALARMOUT, HIGH);
    digitalWrite(ARMEDLED, LOW); //turn LED on
    client->publish(PUBCURRENT,"false"); //turn off the button JIC it is on
    client->publish(PUBCURRENT,"AA");
  }
  else if(msg.compareTo("D")==0){ //target state is D (Disarm)
    currentLevel = level_D;
    digitalWrite(ARMEDLED, HIGH); //turn the LED off
    digitalWrite(ALARMOUT, HIGH); //turn the alarm off JIC it is on
    //indicate with two short beeps
    digitalWrite(ALARMOUT, LOW); delay(30); digitalWrite(ALARMOUT, HIGH);
    delay(600);
    digitalWrite(ALARMOUT, LOW); delay(30); digitalWrite(ALARMOUT, HIGH);
    client->publish(PUBCURRENT,"false"); //turn the button off JIC it is on
    client->publish(PUBCURRENT,"D");
  }
  else if(msg.compareTo("false")==0) { //a sensor or human turned off the switch   
    digitalWrite(ALARMOUT, HIGH); //turn the alarm off anyway
    if(currentLevel == level_AA){ // if AA, alarm likely to have been triggered
      client->publish(PUBCURRENT,"AA"); //return to AA from T 
    }
  }
  else if(msg.compareTo("true")==0) { //sensor turned on the switch
    if(currentLevel == level_AA){ //if it is armed
      client->publish(PUBCURRENT,"T"); //trigger the security system
      digitalWrite(ALARMOUT, LOW); //turn on the alarm buzzer
    }
    else{ //if currentLevel is level_D
      delay(500); //do nothing but just delay for 500 ms.
      client->publish(PUBCURRENT,"false"); //turn off the button on the Home.app
    }
  }
  else if(msg.compareTo("reset")==0) { //reset ESP01 for debug
    client->publish(PUBDEBUG,"Restarting ESP01..."); delay(500);
    //mainly used to retry mDNS and ArduinoOTA connection.
    ESP.restart();
  }
}

void loop() {
  ArduinoOTA.handle();
  client->loop();
}

{
    "type": "securitySystem",
        "name": "Security System",
        "topics": {
            "setTargetState": "mqttthing/security/setTargetState",
            "getCurrentState": "mqttthing/securit/getCurrentState"
        },
        "restrictTargetState": [
            1,
            3
        ],
        "accessory": "mqttthing"
},

{
    "type": "switch",
    "name": "Alarm Buzzer",
    "topics": {
        "getOn": "mqttthing/security/getCurrentState",
        "setOn": "mqttthing/security/setTargetState"
    },
    "accessory": "mqttthing"
},